blob: 1928fbbdb501e960208748fe6d027f17573291e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
set(QEMU_DEMO_DIR ${CMAKE_CURRENT_LIST_DIR})
add_executable(kernel.elf EXCLUDE_FROM_ALL
${QEMU_DEMO_DIR}/demo_threadx.c
${QEMU_DEMO_DIR}/entry.S
${QEMU_DEMO_DIR}/uart.c
${QEMU_DEMO_DIR}/plic.c
${QEMU_DEMO_DIR}/hwtimer.c
${QEMU_DEMO_DIR}/trap.c
${QEMU_DEMO_DIR}/board.c
${QEMU_DEMO_DIR}/tx_initialize_low_level.S
)
target_link_libraries(kernel.elf PRIVATE threadx gcc)
target_include_directories(kernel.elf PRIVATE
${CMAKE_SOURCE_DIR}/common/inc
${CMAKE_SOURCE_DIR}/ports/${THREADX_ARCH}/${THREADX_TOOLCHAIN}/inc
${QEMU_DEMO_DIR}
)
target_link_options(kernel.elf PRIVATE
-T${QEMU_DEMO_DIR}/link.lds
-nostartfiles
-Wl,-Map=kernel.map
)
find_package(Python3 COMPONENTS Interpreter)
find_program(RISCV64_GDB NAMES riscv64-unknown-elf-gdb gdb-multiarch)
find_program(RISCV64_QEMU NAMES qemu-system-riscv64)
if(Python3_FOUND AND RISCV64_GDB AND RISCV64_QEMU)
add_custom_target(check-functional-riscv64
COMMAND ${Python3_EXECUTABLE}
${QEMU_DEMO_DIR}/test/threadx_test_tx_gnu_riscv64_qemu.py
--elf $<TARGET_FILE:kernel.elf>
--qemu ${RISCV64_QEMU}
--gdb ${RISCV64_GDB}
DEPENDS kernel.elf
WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
COMMENT "Running RISC-V64 QEMU/GDB functional test runner..."
)
elseif(NOT Python3_FOUND)
message(STATUS
"Python3 not found; check-functional-riscv64 target unavailable.")
elseif(NOT RISCV64_GDB)
message(STATUS
"RISC-V GDB not found; check-functional-riscv64 target unavailable.")
else()
message(STATUS
"qemu-system-riscv64 not found; check-functional-riscv64 target unavailable.")
endif()
|
