blob: 42f08fb6e2d41b0771b1b6314c1fe629dc6f9ce0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
/***************************************************************************
* Linker script for RISC-V QEMU virt regression tests.
* Provides 128 MB RAM starting at 0x80000000 (QEMU virt default).
* System stack is 16 KB to accommodate test framework overhead.
**************************************************************************/
OUTPUT_ARCH( "riscv" )
ENTRY( _start )
MEMORY
{
RAM (rwx) : ORIGIN = 0x80000000, LENGTH = 128M
}
SECTIONS
{
. = 0x80000000;
.text : {
KEEP(*(.text.init))
*(.text .text.*)
. = ALIGN(0x1000);
PROVIDE(etext = .);
} > RAM
.rodata : {
. = ALIGN(16);
*(.srodata .srodata.*)
. = ALIGN(16);
*(.rodata .rodata.*)
} > RAM
.data : {
. = ALIGN(16);
*(.sdata .sdata.*)
. = ALIGN(16);
*(.data .data.*)
} > RAM
.bss : {
. = ALIGN(16);
_bss_start = .;
*(.sbss .sbss.*)
. = ALIGN(16);
*(.bss .bss.*)
*(COMMON)
_bss_end = .;
} > RAM
.stack : {
. = ALIGN(4096);
_sysstack_start = .;
. += 0x4000;
_sysstack_end = .;
} > RAM
PROVIDE(_end = .);
ASSERT(. <= ORIGIN(RAM) + LENGTH(RAM), "Image exceeds available RAM")
}
|
